NL/Documentation/How Tos/Calc: functie VERT.ZOEKEN

From Apache OpenOffice Wiki
< NL‎ | Documentation‎ | How Tos
Revision as of 13:17, 30 November 2009 by Ccornell (Talk | contribs)

(diff) ← Older revision | Latest revision (diff) | Newer revision → (diff)
Jump to: navigation, search


VERT.ZOEKEN

Geeft een waarde terug uit een tabelkolom, in de rij die werd gevonden door een zoekactie in de eerste kolom.

Syntaxis:

VERT.ZOEKEN(opzoekwaarde; gegevenstabel; kolomindex; modus)

opzoekwaarde is een waarde (getal, tekst of logische waarde) om op te zoeken in de linker kolom van het bereik/de matrix gegevenstabel. Als een waarde overeenkomt met de linker kolom, geeft VERT.ZOEKEN de overeenkomende waarde (in dezelfde rij) in de kolomindexe kolom van gegevenstabel terug, waar kolomindex = 1 de linker kolom is.
Als modus 0 is of ONWAAR, mag de linker kolom van gegevenstabel ongeordend zijn, en wordt de eerste exacte overeenkomst gevonden (zoekend van boven naar beneden).
Als modus 1 of WAAR, of wordt weggelaten, moet de linker kolom van gegevenstabel gesorteerd zijn, met getallen in oplopende volgorde vóór tekstwaarden in alfabetische volgorde. VERT.ZOEKEN bepaalt waar in de linker kolom opzoekwaarde moet verschijnen. Als er een exacte overeenkomst is, is dat de gevonden rij; als er meer dan één exacte overeenkomst is, is de gevonden rij niet noodzakelijkerwijze het dichtste bij de bovenste. Als er geen exacte overeenkomst is, wordt de rij boven die waar waarde zou moeten verschijnen in de linker kolom gevonden; de fout #N/B is het resultaat als die rij niet in de tabel aanwezig is.


Als reguliere expressies zijn ingeschakeld in het dialoogvenster Extra - Opties - OpenOffice.org Calc - Berekenen, zal VERT.ZOEKEN exacte overeenkomsten vinden waarbij opzoekwaarde wordt behandeld als een * reguliere expressie. Dit heeft alleen zin en zou alleen moeten worden gebruikt als modus 0 is of ONWAAR.
Als 'Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn' is ingeschakeld in het dialoogvenster Extra - Opties - OpenOffice.org Calc - Berekenen, moet opzoekwaarde overeenkomen met de gehele tekst in de cel; indien niet, kan het overeenkomen met elk gedeelte van de tekst.
Het overeenkomen is altijd hoofdletterongevoelig - de instelling hoofd-/kleine letters in het dialoogvenster Extra - Opties - OpenOffice.org Calc - Berekenen is niet van toepassing.

Voorbeelden:

In deze voorbeelden bevatten de cellen A1 tot en met A5 3, 5, kat, mat en matten, en de cellen B1 tot en met B5 bevatten A, B, C, D en E.

Calc vlookup example nl.png

VERT.ZOEKEN(3; A1:B5; 2; 0)

geeft A terug. Cel A1 in de linker kolom komt overeen met 3. De inhoud van de overeenkomende cel in de 2e kolom (dat is B1) wordt teruggegeven. De linker kolom is weliswaar gesorteerd, maar dat is niet noodzakelijk in de modus 0.

VERT.ZOEKEN(4; A1:B5; 2; 0)

geeft #N/B terug. Er is geen overeenkomst voor 4.

VERT.ZOEKEN("KAT"; A1:B5; 2; 0)

geeft C terug. Het verschil tussen hoofd- en kleine letters wordt genegeerd, dus KAT komt overeen met kat.

VERT.ZOEKEN("k.t"; A1:B5; 2; 0)

geeft C terug als reguliere expressies zijn ingeschakeld (en #N/B indien niet). De punt '.' staat voor 'elk enkel teken' in een reguliere expressie, dus komt k.t overeen met kat.

VERT.ZOEKEN(".at"; A1:B5; 2; 0)

geeft C terug als reguliere expressies zijn ingeschakeld. kat komt overeen; als ook mat, maar de overeenkomst die het dichtste bij de bovenste is wordt altijd gevonden in modus 0.

VLOOKUP("at"; A1:B5; 2; 0)

geeft #N/B terug als 'Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn' is ingeschakeld en anders C. at komt niet overeen met de inhoud van een gehele cel, maar komt overeen met een gedeelte van kat.

VERT.ZOEKEN(3; A1:B5; 2; 1)

geeft A terug. Cel A1 in de linker kolom komt overeen met 3. De linker kolom moet in modus 1 gesorteerd zijn, waarbij tekst na getallen komt. matten volgt op mat omdat, hoewel de eerste letters hetzelfde zijn, matten meer letters heeft.

VERT.ZOEKEN(4; A1:B5; 2; 1)

geeft A terug. 4 zal verschijnen tussen 3 en 5 in de linker kolom, dus wordt de positie er boven gevonden.

VERT.ZOEKEN(1; A1:B5; 2; 1)

geeft #N/B terug. 1 zal verschijnen voor 3 in de linker kolom, en er is geen positie daar boven in de tabel.

VERT.ZOEKEN(7; A1:B5; 2; 1)

geeft B terug. 7 zal verschijnen tussen 5 en kat in de linker kolom, dus wordt de positie daar boven gevonden.

VERT.ZOEKEN("appel"; A1:B5; 2; 1)

geeft B terug. appel zal verschijnen tussen 5 en kat in de linker kolom, dus wordt de positie daar boven gevonden.

VERT.ZOEKEN("mate"; A1:B5; 2; 1)

geeft D terug. mate zou verschijnen tussen mat en matten in de linker kolom, dus de positie daar boven wordt gevonden.

VERT.ZOEKEN("rat"; A1:B5; 2; 1)

geeft E terug. rat zal verschijnen na matten in de linker kolom, dus wordt de positie daar boven gevonden.

VERT.ZOEKEN("at"; A1:B5; 2; 1)

geeft B terug, zelfs als 'Zoekcriteria = en <> moeten op hele cellen toepasbaar zijn' is uitgeschakeld. In dit geval wordt de overeenkomst tussen at en kat genegeerd ten faveure van het behandelen van at als één woord dat komt tussen 5 en kat.

Problemen:

  • Het gedrag van de hoofdlettergevoeligheid wordt besproken in Issue 71000 .

Zie ook

Personal tools