Difference between revisions of "Documentation/How Tos/Calc: HYPERLINK function"

Latest revision as of 12:25, 2 February 2024

HYPERLINK

Sets a cell to open a hyperlink (in another application) when clicked.

Syntax:

HYPERLINK(linkaddress; celltext)

A cell containing a HYPERLINK function will open a hyperlink when the cell is clicked.

linkaddress is the address (as text) that is opened. celltext is the text displayed in the cell. If celltext is omitted, linkaddress is displayed in the cell.

To edit a hyperlinked cell, select a nearby cell, and navigate to the hyperlinked cell using the keyboard arrows (if you click directly, it will open the hyperlink).

For common, straightforward usage of HYPERLINK, see the Examples section.

If you need a fuller explanation of the unique way in which HYPERLINK works, it follows now:

If a cell contains a HYPERLINK function (even if the HYPERLINK function is not evaluated):

1. that cell becomes a hyperlinked cell; that is, if you click on it, it will attempt to open a page in a browser window.

For example, in a cell with
=IF(TRUE(); "some text"; HYPERLINK("http://www.example.com"))
the HYPERLINK function is never evaluated - but nevertheless the cell becomes a hyperlinked cell (although the link will fail - see 2. below).

2. the formula in the cell is evaluated twice.

i) The first time, any HYPERLINK function returns linkaddress, and the result of the formula becomes the address to link to.

ii) The second time, any HYPERLINK function returns celltext (or linkaddress if no celltext is given), and the result of the formula is displayed in the cell.

For example,
= "h" & HYPERLINK("ttps://"; "ot ") & HYPERLINK("www.example.com"; "link") evaluates twice. The first time "h" & "ttps://" & "www.example.com" are concatenated to form "http://www.example.com" - the address to link to. The second time "h" & "ot " & "link" are concatenated to form "hot link" - the text that appears in the cell.

For example,
= "h" & HYPERLINK("ttps://"; "ere is ") & HYPERLINK("www.example.com") evaluates firstly to concatenate "h" & "ttps://" & "www.example.com", forming "http://www.example.com" - the address to link to, and secondly to concatenate "h" & "ere is " & "www.example.com", forming "here is www.example.com" - the text that appears in the cell.

3. If any error is returned, the cell ceases to be a hyperlinked cell.

The examples above illustrate how HYPERLINK works - but not how it should be used.

Example:

=HYPERLINK("https://www.example.org")

displays https://www.example.org in the cell and opens the hyperlink https://www.example.org when clicked.

=HYPERLINK("https://www.example.org"; "Click here")

displays Click here in the cell and opens the hyperlink https://www.example.org when clicked.

=HYPERLINK("https://www."; "Click ") & "example.org"

displays Click example.org in the cell and opens the hyperlink https://www.example.org when clicked.

Issues:

• Text rotated through 90 degrees may not be clickable (Issue 74471 ).
• The mouse pointer may not revert after leaving the "Format Cells" dialog (Issue 74490 ).

• Spreadsheet functions

• Functions listed alphabetically
• Functions listed by category