Difference between revisions of "EN/Documentation/BASIC Guide/Rows and Columns"

Revision as of 18:22, 25 June 2009

Template:EN/Documentation/BASICGuideTOC/v2

Ogni foglio contiene un elenco delle righe e delle colonne, che sono disponibili tramite le proprietà Rows e Columns dell'oggetto foglio elettronico e supporta i servizi com.sun.star.table.TableColumns e/o com.sun.star.table.TableRows.

L'esempio seguente crea due oggetti che fanno riferimento alla prima riga e alla prima colonna di un foglio e memorizza i riferimenti nelle variabili oggetto FirstCol e FirstRow .

Dim Doc As Object
Dim Sheet As Object
Dim FirstRow As Object
Dim FirstCol As Object
 
Doc = StarDesktop.CurrentComponent
Sheet = Doc.Sheets(0)
 
FirstCol = Sheet.Columns(0)
FirstRow = Sheet.Rows(0)

Gli oggetti colonna supportano il servizio com.sun.star.table.TableColumn che dispone delle seguenti proprietà:

Width (long)

Larghezza di una colonna in centesimi di millimetro.

OptimalWidth (Boolean)

Imposta una colonna sulla sua larghezza ottimale.

IsVisible (Boolean)

Visualizza una colonna.

IsStartOfNewPage (Boolean)

Nella stampa, crea un'interruzione di pagina prima di una colonna.

La larghezza di una colonna viene ottimizzata solo quando la proprietà OptimalWidth è impostata su True. Se viene modifica la larghezza di una singola cella, la larghezza della colonna che contiene la cella rimane invariata. In termini di funzionalità, OptimalWidth è più un metodo che una proprietà.

Gli oggetti riga sono basati sul servizio com.sun.star.table.RowColumn, che dispone delle seguenti proprietà:

Height (long)

Altezza della riga in centesimi di millimetro.

OptimalHeight (Boolean)

Imposta una colonna sulla sua altezza ottimale.

IsVisible (Boolean)

Visualizza la riga.

IsStartOfNewPage (Boolean)

Nella stampa, crea un'interruzione di pagina prima della riga.

Se la proprietà OptimalHeight di una riga è impostata su True, l'altezza della riga viene modificata automaticamente quando si varia l'altezza di una cella della riga. L'ottimizzazione automatica prosegue finché alla riga non è assegnata un'altezza assoluta mediante la proprietà Height.

L'esempio seguente attiva l'ottimizzazione automatica dell'altezza per le prime cinque righe del foglio e rende invisibile la seconda colonna.

Dim Doc As Object
Dim Sheet As Object
Dim Row As Object
Dim Col As Object
Dim I As Integer
 
Doc = StarDesktop.CurrentComponent
Sheet = Doc.Sheets(0)
 
For I = 0 To 4
   Row = Sheet.Rows(I)
   Row.OptimalHeight = True
Next I
 
Col = Sheet.Columns(1)
Col.IsVisible = False

Template:Documentation/Note

Inserimento ed eliminazione di righe o colonne

Gli oggetti Rows e Columns di un foglio possono accedere alle righe e alle colonne già esistenti nonché inserirle o modificarle.

Dim Doc As Object
Dim Sheet As Object
Dim NewColumn As Object
 
Doc = StarDesktop.CurrentComponent
Sheet = Doc.Sheets(0)
 
Sheet.Columns.insertByIndex(3, 1)
Sheet.Columns.removeByIndex(5, 1)

Questo esempio utilizza il metodo insertByIndex per inserire una nuova colonna nella posizione della quarta colonna nel foglio (indice 3; la numerazione inizia da 0). Il secondo parametro specifica il numero di colonne da inserire (in questo esempio: uno).

Il metodo removeByIndex elimina la sesta colonna (indice 5). Ancora una volta, il secondo parametro specifica il numero di colonne da eliminare.

I metodi di inserimento ed eliminazione delle righe utilizzando la funzione dell'oggetto Rows nello stesso modo dei metodi illustrati per la modifica delle colonne utilizzando l'oggetto Columns.